Transferir um Recordset para um arquivo txt, utilizando o DAO

Nota importante: para ter acesso aos vídeos e arquivos exemplos deste site, adquira um dos planos apresentados abaixo. Você pode comprar em até 5x no Cartão de Crédito.

Veja como comprar e saiba mais sobre o material oferecido, clicando aqui.

Open v3

Observe a lista abaixo que é o resultado de uma consulta:

Palavra	Sinônimo
Renovar	Melhorar
Renovar	Aperfeiçoar
Renovar	Esmerar
Trajetória	Caminho
Trajetória	Carreira
Rodar	Girar
Rodar	Virar

O objetivo neste exemplo é gerar um arquivo txt, com a seguinte formatação:

Renovar ={"Melhorar","Aperfeiçoar","Esmerar"}
Trajetória ={"Caminho","Carreira"}
Rodar ={"Girar","Virar"}

Acompanhe os comentários do código que abre o Recordset da consulta e monta as linhas do txt, conforme o layout desejado:

Private Sub btCriarTxt_Click()
Dim rs As DAO.Recordset
Dim strLinha As String
Dim strPalavra As String

'-------------------------------------------

'Abre o Recordset da consulta, utilizando o DAO

'-------------------------------------------
Set rs = CurrentDb.OpenRecordset("qrySinonimos")

'--------------------

'Cria o arquivo txt

'-------------------
Open "c:\MinhaPasta\meuArquivo.txt" For output As #1

  '-------------------------------------------------

  'Inicia um loop por todos os registros da consulta

  '-------------------------------------------------

  Do While Not rs.EOF
    strPalavra = rs!palavra

    '--------------------------------------------------------

    'Armazena na variável, a formatação inicial de cada linha

    '--------------------------------------------------------
    strLinha = rs!palavra & " ={"

      '----------------------------------------------------

      'Agrupa os valores do campo sinônimo da palavra atual

      '-----------------------------------------------------
      Do While strPalavra = rs!palavra
        strLinha = strLinha & Chr(34) & rs!sinonimo & Chr(34) & ","
        rs.MoveNext
        If rs.EOF Then Exit Do
      Loop

    '-------------------------------------------------------------------

    'Monta a formatação final da palavra com os seus sinônimos agrupados

    '--------------------------------------------------------------------
    strLinha = Left(strLinha, Len(strLinha) - 1)
    strLinha = strLinha & "}"

    '--------------------------------

    'Grava a montagem da linha no txt

    '--------------------------------
    Print #1, strLinha
  Loop
  rs.Close
  Set rs = Nothing
Close #1
MsgBox "Montagem concluída...", vbInformation, "Aviso"
End Sub

Clique aqui e baixe o exemplo para você testar e praticar.

Bom estudo!

Os dez artigos mais visitados

MontaRibbons v.7.0 - Assistente completo para criar ribbons no Access

Vídeo - Controle personalizado de Acesso de Usuários

Vídeo - Aprenda sobre filtragens

Vídeo - Segurança máxima, usando o OPEN

Uma ajuda para quem está começando um negócio ou um projeto

Integrando o Access com Servidor MySQL - Introdução

Desabilitando a faixa(ribbon) superior do Access

Vídeo - Programação de relatórios - Parte 1

Como carregar o seu menu sem que ele vá para lista de suplementos

Vídeo - Criando Ribbons parte 1  - Conhecendo a estrutura Xml

| Home | Vídeos | Tutoriais | Dicas | Ribbons | Suporte | Downloads | Contato | Artigo |

Não há comentário

Usando Access

Transferir um Recordset para um arquivo txt, utilizando o DAO